这道题真毒瘤

虽然是本蒟蒻纯靠自己A的第一道紫题

不管怎么说，这道题也是编了3天的，交了差不多10次

好了，言归正传，这道题到底怎么做呢？

首先，这道题用C++肯定不方便，毕竟字符串处理题，所以目标选定pascal（会两种语言就是好）。

然后，我们来思考怎么构建这个程序。

你的第一个想法基本上是：一行一行做下来，然后用一些数组记录每个变量，然后每做到一个变量或每句话判断一下。

然而，很显然，只做一遍是很难实现的，至少在逻辑上不是很简单。

所以，我的方法是这样的：

1. 将原来的代码简化成一些简单的符号表示，并计算出总行数$n$
2. 处理PARAM语句
3. 依次从第$2$行到第$n$行做下来，这一遍只判断是否有unreachable的情况，在这一遍中，遇到的变量用一个$judge$判断
4. 对于每一个$judge$而言，我们从头开始再做一遍

这是第一，二部分

xxxxxxxxxx
procedure swap(var x,y:char);//交换
var t:char;
begin
  t:=x;x:=y;y:=t;
end;
function got(var st:string):string;//在一个字符串中读取一段子串
var k:longint;
begin
  k:=pos(' ',st);//找到最近的空格
  got:=copy(st,1,k-1);
  delete(st,1,k);//删掉不要的东西
end;
function compare(s1,s2:string):boolean;//判断s1的前面若干位是否等于s2
begin
  if copy(s1,1,length(s2))=s2 then exit(true);
  exit(false);
end;
procedure start;//开始读入+转化
var st:string;a,b,c:char;
begin
  readln(st);st:=st+' ';//加空格是为了got语句的方便
  delete(st,1,6);//把PARAM这个单词删去
  while st<>'' do f[got(st)[1]]:=true;//处理一开始就定义的变量
  line:=1;//行数
  while not(eof) do
  begin
    inc(line);
    readln(st);st:=st+' ';
    if compare(st,'IF') then//IF语句
    begin
      delete(st,1,3);
      a:=got(st)[1];got(st);b:=got(st)[1];
      if a=b then b:=' ';//两个相同只要做一个
      if a>b then swap(a,b);//两个必须按顺序排列，不然以后调用错误1时会很麻烦
      op[line]:=1;//操作类型
      ct[line,1]:=a;//操作变量1
      ct[line,2]:=b;//操作变量2
    end else
    if compare(st,'END IF') then op[line]:=3
    else if compare(st,'ELSE') then op[line]:=2
    else if compare(st,'RETURN') then
    begin
      delete(st,1,7);
      op[line]:=4;
      ct[line,1]:=got(st)[1];
    end
    else
    begin
      op[line]:=0;
      a:=got(st)[1];got(st);b:=got(st)[1];
      if st<>'' then//如果还有第三个参数
      begin
        got(st);c:=got(st)[1];
        if b=c then c:=' ';
        if b>c then swap(b,c);
        ct[line,1]:=b;
        ct[line,2]:=c;
      end
      else ct[line,1]:=b;
      ct[line,3]:=a;//操作变量3
    end;
  end;
end;

这是第三部分

我们用$level$来记录当前的级别

我们用$stack2$数组来记录当前级别内是处于$if$模式还是$else$模式

我们用$noerror1$来记录是否可以出现错误1，即如果这句话没有被做到的话，$noerror1=true$

我们用$die$数组来记录在该级别，该模式下是否存在过$return$，若有，即为$true$

值得注意的是，如果$die[i,0]=die[i,1]=true$那么$die[i-1,stack2[i-1]]=true$

这点相当于

xxxxxxxxxx
PARAM A
IF A > 0 THEN
RETURN 0
ELSE
RETURN 0
END IF
RETURN P

第7行是不会被做到的

如果做一句话的时候，$die[level,stack2[level]]=true$，且这句话不为$else$和$end if$，那么报告2错误。

记住，stack2不要打成stack，就因为这一点，我浪费了2个小时！

xxxxxxxxxx
function ischar(a:char):boolean;
begin
  if (a>='A') and (a<='Z') then exit(true);
  exit(false);
end;
procedure error2(line:longint);
begin
  writeln('Line ',line,': unreachable code');
end;
procedure run;
var level,i:longint;
    noerror1:boolean;
    none:longint;
begin
  level:=1;
  stack2[1]:=0;
  for i:=2 to line do
  begin
    noerror1:=false;
    if (die[level,stack2[level]])and(op[i] in [0,1,4]) then//如果这句话$die$了（即没有办法做到）
    begin
      error2(i);noerror1:=true;
    end;
    case op[i] of
    1:begin//if
        inc(level);//下一级别
        stack2[level]:=0;
        if die[level-1,stack2[level-1]] then//如果上一级就die了，那么下一级就更die了
        begin
          die[level,0]:=true;
          die[level,1]:=true;
        end
        else
        begin
          die[level,0]:=false;
          die[level,1]:=false;
        end;
        if noerror1=false then
        begin
          if ischar(ct[i,1]) then judge(ct[i,1],i,level);//判断参数一是否错误
          if ischar(ct[i,2]) then judge(ct[i,2],i,level);//判断参数2是否错误 
        end;
      end;
    2:begin//else
        stack2[level]:=1;//从if模式换到else模式
      end;
    3:begin//end if
        die[level,0]:=false;die[level,1]:=false;
        dec(level);//上一级别
      end;
    4:begin//return
        die[level,stack2[level]]:=true;//这一级的这一模式die了
        if noerror1=false then
        begin
          if ischar(ct[i,1]) then judge(ct[i,1],i,level);
        end;
        if (die[level,0])and(die[level,1]) then//die记号上传
        begin
          die[level-1,stack2[level-1]]:=true;
        end;
      end;
    0:begin//赋值语句
        if noerror1=false then
        begin
          if ischar(ct[i,1]) then judge(ct[i,1],i,level);
          if ischar(ct[i,2]) then judge(ct[i,2],i,level);
        end;
      end;
    end;
  end;
end;

第四部分

同样用一个$stack$数组，一个$get$数组（和$die$相似）

用一个$unreach$来表示这一句话是否可以被做到，如果不能做到，那么这一句赋值就是白搭（如果你想的话也可以再用一次$die$数组哦）

xxxxxxxxxx
procedure error1(line:longint;c:char);
begin
  writeln('Line ',line,': variable ',c,' might not have been initialized');
end;
procedure judge(c:char;line,lvl:longint);
var level,unreach:longint;
    i,j:longint;
begin
  if f[c] then exit;//如果本来就在PARAM里出现过那就直接ok
  level:=1;unreach:=0;
  for i:=1 to 100 do
    for j:=0 to 1 do
      get[i,j]:=false;//fillchar出毛病了，所以手动改
  for i:=1 to 100 do stack[i]:=0;
  stack[level]:=0;
  for i:=2 to line-1 do
  begin
    case op[i] of
      0:begin//赋值语句
          if (ct[i,3]=c)and(unreach=0) then//如果被赋值的参数里有目标参数，且可以被做到，那么这一级别的这一模式可以被录用
            get[level,stack[level]]:=true;
        end;
      1:begin//if
          inc(level);stack[level]:=0;
        end;
      2:begin//else
          stack[level]:=1;
          if unreach=level then unreach:=0;//die的简化版，如果就在这一级别前面的if被咔嚓了，那么免除死刑
        end;
      3:begin//end if
          if get[level,1] and get[level,0] then//get标记上传（同die标记）
          begin
            get[level-1,stack[level-1]]:=true;
          end;
          get[level,1]:=false;get[level,0]:=false;//注意清空
          if unreach=level then unreach:=0;
          dec(level);
        end;
      4:begin
          get[level,stack[level]]:=true;//return也可以表示这个变量被赋值（见注释1）
          if unreach=0 then unreach:=level;
        end;
      end;
  end;
  if get[1,0] then exit;//如果在最外层被赋值直接ok
  for i:=2 to lvl-1 do
  begin
    if get[i,1] or get[i,0] then exit;//前面一句话的展开版本
  end;
  if get[lvl,stack[level]] then exit;//最后一层必须在同一模式内（见注释2）
  error1(line,c);//啥都没找到返回错误
end;

注释1：

xxxxxxxxxx
PARAM A
IF A > 0 THEN
RETURN A
ELSE
K = A
END IF
RETURN K

这里不该返回错误

注释2：

xxxxxxxxxx
PARAM A
IF A > 0 THEN
K = A
ELSE
RETURN K
END IF

这里应该在第5行返回错误

还有一些容易出错的地方：

xxxxxxxxxx
PARAM A
A = A + 1
第2行出错
​
PARAM A
IF A > 0 THEN
RETURN 0
ELSE
RETURN 0
END IF
C = K
第7行应该返回unreachable的错误
​
PARAM A
IF A > 0 THEN
K = 1
ELSE
K = 2
END IF
C = K
没有错误

再次提醒：变量名不要弄混了！！！

完整代码

xxxxxxxxxx
var stack,stack2,op:array[0..100]of longint;
    get,die:array[0..100,0..1]of boolean;
    ct:array[0..100,0..3]of char;
    f:array['A'..'Z']of boolean;
    line:longint;
function ischar(a:char):boolean;
begin
  if (a>='A') and (a<='Z') then exit(true);
  exit(false);
end;
procedure swap(var x,y:char);
var t:char;
begin
  t:=x;x:=y;y:=t;
end;
procedure error1(line:longint;c:char);
begin
  writeln('Line ',line,': variable ',c,' might not have been initialized');
end;
procedure error2(line:longint);
begin
  writeln('Line ',line,': unreachable code');
end;
function got(var st:string):string;
var k:longint;
begin
  k:=pos(' ',st);
  got:=copy(st,1,k-1);
  delete(st,1,k);
end;
function compare(s1,s2:string):boolean;
begin
  if copy(s1,1,length(s2))=s2 then exit(true);
  exit(false);
end;
procedure start;
var st:string;a,b,c:char;
begin
  readln(st);st:=st+' ';
  delete(st,1,6);
  while st<>'' do f[got(st)[1]]:=true;
  line:=1;
  while not(eof) do
  begin
    inc(line);
    readln(st);st:=st+' ';
    if compare(st,'IF') then
    begin
      delete(st,1,3);
      a:=got(st)[1];got(st);b:=got(st)[1];
      if a=b then b:=' ';
      if a>b then swap(a,b);
      op[line]:=1;
      ct[line,1]:=a;
      ct[line,2]:=b;
    end else
    if compare(st,'END IF') then op[line]:=3
    else if compare(st,'ELSE') then op[line]:=2
    else if compare(st,'RETURN') then
    begin
      delete(st,1,7);
      op[line]:=4;
      ct[line,1]:=got(st)[1];
    end
    else
    begin
      op[line]:=0;
      a:=got(st)[1];got(st);b:=got(st)[1];
      if st<>'' then
      begin
        got(st);c:=got(st)[1];
        if b=c then c:=' ';
        if b>c then swap(b,c);
        ct[line,1]:=b;
        ct[line,2]:=c;
      end
      else ct[line,1]:=b;
      ct[line,3]:=a;
    end;
  end;
end;
procedure judge(c:char;line,lvl:longint);
var level,unreach:longint;
    i,j:longint;
begin
  if f[c] then exit;
  level:=1;unreach:=0;
  for i:=1 to 100 do
    for j:=0 to 1 do
      get[i,j]:=false;
  for i:=1 to 100 do stack[i]:=0;
  stack[level]:=0;
  for i:=2 to line-1 do
  begin
    case op[i] of
      0:begin
          if (ct[i,3]=c)and(unreach=0) then
            get[level,stack[level]]:=true;
        end;
      1:begin
          inc(level);stack[level]:=0;
        end;
      2:begin
          stack[level]:=1;
          if unreach=level then unreach:=0;
        end;
      3:begin
          if get[level,1] and get[level,0] then
          begin
            get[level-1,stack[level-1]]:=true;
          end;
          get[level,1]:=false;get[level,0]:=false;
          if unreach=level then unreach:=0;
          dec(level);
        end;
      4:begin
          get[level,stack[level]]:=true;
          if unreach=0 then unreach:=level;
        end;
      end;
  end;
  if get[1,0] then exit;
  for i:=2 to lvl-1 do
  begin
    if get[i,1] or get[i,0] then exit;
  end;
  if get[lvl,stack[level]] then exit;
  error1(line,c);
end;
procedure run;
var level,i:longint;
    noerror1:boolean;
    none:longint;
begin
  level:=1;
  stack2[1]:=0;
  for i:=2 to line do
  begin
    noerror1:=false;
    if (die[level,stack2[level]])and(op[i] in [0,1,4]) then
    begin
      error2(i);noerror1:=true;
    end;
    case op[i] of
    1:begin
        inc(level);
        stack2[level]:=0;
        if die[level-1,stack2[level-1]] then
        begin
          die[level,0]:=true;
          die[level,1]:=true;
        end
        else
        begin
          die[level,0]:=false;
          die[level,1]:=false;
        end;
        if noerror1=false then
        begin
          if ischar(ct[i,1]) then judge(ct[i,1],i,level);
          if ischar(ct[i,2]) then judge(ct[i,2],i,level);
        end;
      end;
    2:begin
        stack2[level]:=1;
      end;
    3:begin
        die[level,0]:=false;die[level,1]:=false;
        dec(level);
      end;
    4:begin
        die[level,stack2[level]]:=true;
        if noerror1=false then
        begin
          if ischar(ct[i,1]) then judge(ct[i,1],i,level);
        end;
        if (die[level,0])and(die[level,1]) then
        begin
          die[level-1,stack2[level-1]]:=true;
        end;
      end;
    0:begin
        if noerror1=false then
        begin
          if ischar(ct[i,1]) then judge(ct[i,1],i,level);
          if ischar(ct[i,2]) then judge(ct[i,2],i,level);
        end;
      end;
    end;
  end;
end;
begin
  start;
  run;
end.